Space Curves

Goal:  Become familiar with graphs of curves in three dimensional space and with their projections onto the coordinate planes.  Increase spatial intuition and visualization.

Some examples are done below.  Read the text and examples carefully to understand the commands, then move your cursor to the end of the first input line (the bold face lines are input lines).  To execute the commands press the ENTER  key over on the right side of the keyboard with the numeric keyboard.

Submit printouts of graphs for your lab report as indicated in the exercises.  Please follow the directions given in the exercises.  Each printout must show the complete Mathematica  input line that produced the graph and it has to have the number of the exercise on it.  Number your pages.  Follow any special instructions your instructor has given.

Examples

Curves in space defined by parametric equations

Curves in space that are defined by parametric equations can be graphed with ParametricPlot3D[ ].  ParametricPlot3D[ { x[t], y[t], z[t] }, {t, a, b}]  produces a graph where the  x, y, and  z coordinates of points are generated as functions of the parameter  t.  You can add color to the curve by inserting a color specification after the last coordinate function, as is done in the first example below.  To familiarize yourself with ParametricPlot3D[ ], enter the examples that follow.

EXAMPLE 1:  If we want to look at the vector function  r(t) = t i + (1 - t) j + t k  the function, we need to load a package within Mathematica.  This is done by entering the following line.

Needs["Graphics`ParametricPlot3D`"]

Now, we can use the Parametric Plot3D[ ] command

ParametricPlot3D[{t, 1 - t, t}, {t, 0, 1}, 
      AxesLabel -> {x, y, z}];

This curve  x = t,  y = 1 - t, z = t  is a straight line connecting the points  (0, 1, 0)  and  (1, 0, 1).  Make sure you know where the origin of the coordinate system is located in this graph.  The next line simply directs Mathematica to display the line in red.

ParametricPlot3D[{t, 1 - t, t, RGBColor[1, 0, 0]}, {t, 0, 1}, 
      AxesLabel -> {x, y, z}];

We look at the line again but this time change the viewpoint.  Viewpoint->{a,b,c} sets the point from which to look at the surface.  The default viewpoint is located at the the point (1.3, -2.4, 2) which presents the axes in a different orientation than we see in most textbooks.  By choosing all positive entries for the viewpoint, the axes will be in "standard orientation" with the positive x-axis coming out toward us and the positive y-axis running toward the right.

ParametricPlot3D[{t, 1 - t, t}, {t, 0, 1}, AxesLabel -> {x, y, z}, 
      ViewPoint -> {3, 1.3, 1}];

EXAMPLE 2:  Following is another straight line in space displayed first with Mathematica's default viewpoint and then with the viewpoint set at (3, 1.3, 1).  Again, make sure you know where the origin of the coordinate system is located.  Also, find the initial and terminal points for the given t-interval.

ParametricPlot3D[{t, 1 - t, (1/2)}, {t, 0, 1}, 
      AxesLabel -> {x, y, z}];

ParametricPlot3D[{t, 1 - t, (1/2)}, {t, 0, 1}, 
      AxesLabel -> {x, y, z}, 
      ViewPoint -> {3, 1.3, 1}];

EXAMPLE 3:  The next three graphs are examples of circular helices.  Enter all three and in each graph locate the origin and the positive direction of the coordinate axes.  BoxRatios->{a,b,c} sets the side length ratios for the box enclosing the surface; the default BoxRatios are {1, 1, 0.4}, setting  BoxRatio->Automatic gives identical scales on each side.

ParametricPlot3D[{Cos[t], Sin[t], t}, {t, -2 π, 2 π}, 
      AxesLabel -> {x, y, z}, BoxRatios -> {1, 1, 1}, 
      ViewPoint -> {3, 1.3, 1}];

ParametricPlot3D[{t, Cos[t], Sin[t]}, {t, -2 π, 2 π}, 
      AxesLabel -> {x, y, z}, BoxRatios -> {1, 1, 1}, 
      ViewPoint -> {3, 1.3, 1}];

ParametricPlot3D[{Cos[t], t, Sin[t]}, {t, -2 π, 2 π}, 
      AxesLabel -> {x, y, z}, BoxRatios -> {1, 1, 1}, 
      ViewPoint -> {3, 1.3, 1}];

EXAMPLE 4:  The curves given parametrically by  x = A t,  y = B t2,  z = C t3  are called twisted cubics.  For reasons of visual clarity we will consider first the case  A = 1, B = 0.5  and  C = 0.2.  Enter the line below to see the twisted cubic.

a = 
      ParametricPlot3D[{t, 0.5 (t^2), 0.2 (t^3), 
          RGBColor[1, 0, 0]}, {t, -2, 2}, BoxRatios -> {1, 1, 1}, 
        AxesLabel -> {x, y, z}, 
        PlotRange -> {{-2, 2}, {0, 2}, {-2, 2}}, 
        ViewPoint -> {3, 1, 1}];

The PlotRange statement above restricts the graph to -2 ≤ x ≤ 2,  0 ≤y ≤ 2, and -2 ≤ z ≤ 2.

To get a better sense of the curve we will project the curve onto the coordinate planes.  This is done by setting one of the variables  x, y,  or  z  equal to zero and considering the plane curves in the coordinate planes.  Enter the following lines to see the projections of the curve.

b = 
      ParametricPlot3D[{t, 0.5 (t^2), 0, RGBColor[0, 0, 1]}, {t, -2, 2}, 
        BoxRatios -> {1, 1, 1}, AxesLabel -> {x, y, z}, 
        PlotRange -> {{-2, 2}, {0, 2}, {-2, 2}}, 
        ViewPoint -> {3, 1, 1}];

c = 
      ParametricPlot3D[{t, 0, 0.2 (t^3), RGBColor[1, 0, 0]}, {t, -2, 2}, 
        BoxRatios -> {1, 1, 1}, AxesLabel -> {x, y, z}, 
        PlotRange -> {{-2, 2}, {0, 2}, {-2, 2}}, 
        ViewPoint -> {3, 1, 1}];

d = 
      ParametricPlot3D[{0, 0.5 (t^2), 0.2 (t^3), 
          RGBColor[1, 0, 1]}, {t, -2, 2}, AxesLabel -> {x, y, z}, 
        BoxRatios -> {1, 1, 1}, 
        PlotRange -> {{-2, 2}, {0, 2}, {-2, 2}}, 
        ViewPoint -> {3, 1, 1}];

We now combine the curve with each of its projections.

Show[a,b];

Show[a,c];

Show[a,d];

Show[a,b,c,d];

EXAMPLE 5:  The parametric equations  x = A cos(wt),  y = B sin(wt),  z = C t  represent  cylindrical helices.  We will look at the special case  A = B = 1,  C = 1 /( 2π)  and  w = 2π.

Clear[a,b,c,d]

a = 
      ParametricPlot3D[{Cos[2 π t], Sin[2 π t], 
          (t/(2 π))}, {t, 0, π}, 
        BoxRatios -> {1, 1, 1}];

We can project the helix onto the coordinate axes as we did in the last example.  Below is the projection onto the x-axis.

b = 
      ParametricPlot3D[{0, Sin[2 π t], (t/(2 π))}, {t, 0, π}, 
        BoxRatios -> {1, 1, 1}];

Show[a, b]

Try getting the others,  determine how the projection is being traced out and look at the projections along with the original curve.

Space Curves on Cylinders

Given a vector valued function r(t) = x(t) i + y(t) j + z(t) k, or, equivalently given parametric equations:
				 x = x(t), y = y(t), z = z(t), 
we have seen in the Space Curves lab that we can visualize the curve defined by the vector valued function, or by the parametric equations, by looking at the projections of the curve onto the coordinate planes.  Often this approach does not provide enough information about the curve for us to grasp clearly its shape.  In this lab we will see how to define cylinders based on these projections and how to draw the curve on the cylinders.  We will also see how to present the curve as the intersection of two of these cylindrical surfaces.

We can generate a cylinder based on the projection of C onto the xy-plane whose sides are parallel to the z-axis by dropping the restriction that z = 0 and setting  z = s, where s is a new parameter.  The parametric equations in two parameters, x =x(t), y = y(t), z = s, define this cylinder.  In a similar way, the parametric equations x = x(t), y = s, z = z(t) defines the cylinder generated by the projection of C onto the xz-plane and we also define the cylinder generated by the projection of C onto the yz-plane.

EXAMPLE 6:  Consider the curve defined by r(t) = sin(t) cos(t) i + cos2(t) j + sin(t) k.  We can draw the curve with the following line.

a = 
      ParametricPlot3D[{Sin[t] Cos[t], Cos[t]^2, Sin[t]}, {t, 0, 2 π}, 
        AxesLabel -> {x, y, z}, BoxRatios -> {1, 1, 1}, 
        ViewPoint -> {1.548, 2.799, 1.104}];

The projection of the curve onto the xy-plane can be drawn by

projxy = 
      ParametricPlot3D[{Sin[t] Cos[t], Cos[t]^2, 0}, {t, 0, 2 π}, 
        BoxRatios -> {1, 1, 1}, AxesLabel -> {x, y, z}, 
        ViewPoint -> {1.548, 2.799, 1.104}];

To see the curve together with its projection on the xy-plane we can enter the following line.

Show[a, projxy]

We can now draw the cylinder generated by the projection onto the xy-plane.

cylxy = 
      ParametricPlot3D[{Sin[t] Cos[t], Cos[t]^2, s}, {t, 0, 
          2 π}, {s, -1.1, 1.1}, BoxRatios -> {1, 1, 1}, 
        ViewPoint -> {1.548, 2.799, 1.104}];

We can use the option Shading->False to reduce the amount of memory needed.  In printouts of surfaces this option makes for clearer and faster printing.

cylxy = 
      ParametricPlot3D[{Sin[t] Cos[t], Cos[t]^2, s}, {t, 0, 
          2 π}, {s, -1.1, 1.1}, BoxRatios -> {1, 1, 1}, 
        ViewPoint -> {1.548, 2.799, 1.104}, 
        Shading -> False];

You should draw the projections onto the xz-plane and the yz-plane, naming them projxz and projyz.  You can use Show[ ] to display the curve with each of its projections and you can draw the cylinders generated by each of these projections by following the example.  Use the domain -1.1 ≤ s ≤ 1.1 to guarantee that the cylinder extends past the curve.

Once you have defined all three cylindrical surfaces you can even try combining them, two at a time, using Show[ ] to see their intersections.

For the lab report, show the curve on one of the surfaces obtained from the projections and show  in one printout two of these cylindrical surfaces intersecting.  You should show input lines and give explanations of what is going to be shown or what is being shown.  Do not  print all your graphs. Print only those two which you believe show the curve to best advantage.  You should use taste, discrimination and judgement in your presentation.

Try drawing the curve on the surface defined by the parametric equations
                           x = sin(t) cos(s), y = sin(t) sin(s), z = cos(t)                                                    
 for 0 ≤ t ≤ 2π and 0 ≤ s ≤ 2π. How do we know the curve lies on this surface?   Although the surface is not a cylinder it does give a very good idea of the curve if the ViewPoint we have been employing is used here.

Exercises

1.  For each of the following use Viewpoint->{3, 1.3, 1}, get a printout and on the printout, draw in the origin, label the axes,  and indicate on the printout how the curve is being traced out as the parameter  t  increases.  
   a)  r(t) = t i + (2 + t) j + t k,  0 ≤ t ≤ 1
	
   b)  r(t) = (cos(t) + sin(t)) i + (cos(t) - sin(t)) j + t k,  0 ≤ t ≤ 2 π.

2.  Describe the effect of changing the coefficients in the parametrization for the twisted cubic  
                  x = A t ,  y = B t2 ,  z = C t3.                                                    
Specifically: (i) Describe what happens when  C  is increased or made negative.  (ii) What happens when  A  is increased or made negative and (iii) likewise for  B.  (iv) Suppose  A  and  C  are allowed to approach  0, what is the limiting curve that results?  Write at least three paragraphs. You can also submit pictures if they illustrate a point you are making.

3.  Investigate the curves below.  Look at their projections.  Look for characteristic features of the curve.  What happens when you interchange  x  with  y, or  y  with  z?  Look at the curves from different viewpoints.
     a)  x = t2,  y = 2 t + 1,  z = 3 t2 - 1.  How can you show that this curve passes through the points (1, 3, 2) and (4, -3, 11), but not through (3, 1, 2)?

     b)   x = t cos t,  y = t sin t,  z = t.

     c)   x = (2 + cos(3t/2)) cos t,  y = (2 + cos(3t/2)) sin t,  z = sin(3t/2).  This curve is called the trefoil knot.

4.   Investigate the twisted cubic given by  r(t) = t i  + 0.5 (t^2)j + 0.2 (t^3)k.  Show the twisted cubic drawn on the cylinders generated by the projections of the curve onto the coordinate planes, you might want to change the ViewPoint.  Likewise, you might want to change the ViewPoint for showing the intersection of the cylinders taken two at a time.  Your choice of a domain for the second parameter s will be determined by the extent of the curve.  You should get a printout  for the curve and one of the cylinders generated by a projection and another printout showing the intersection of two of the cylinders.

5.  Investigate the family of curves given parametrically by the equations
			x = cos(t),   y = cosn(t) sin(t),   z = sin(t), 
where n is a positive integer.  Try a few values for n.  You might also change the third equation to
z = sin(mt), for m a positive integer, and see how this affects the curve with n = 2 for example.  Write an essay which describes clearly in words the family of curves as n varies.  Two or three printouts should be used to illustrate your description. For n fixed at 2, describe the effect of letting m vary where
		 x = cos(t), y = cos2(t) sin(t), z = sin(mt). 
Support your description with two or three printouts.